function pareay(args)
*: pareay cctl ny [xw latlonmag tm bm ypm]　図のy座標を決めるのに便利な関数．見延
* function pareay cctl ny [xw latlonmag tm bm ypm]; *for cctl='map'
* function pareay cctl ny [yw           tm bm ypm]; *for cctl!='map'
* cctl='MAP' かその他
* ny: number of ny'th panels from the top
* xw: x-width for parea in inch
* latlonmag: 緯度方向の拡大率、緯度経度ファイルがオープンされていることが必要
* ywCM: ｙ方向のpanel(軸は含めない)の幅CM
* tm:  top margin
* bm:  bottom margin
* ypm: page margine ただしまだ利用していない．
cctl=subwrd(args,1)
ny=subwrd(args,2)
if (cctl='map' | cctl='MAP')
  xwINCH=subwrd(args,3)
  latlonmag=subwrd(args,4)
  TMarginCM=subwrd(args,5);  if TMarginCM='';  TMarginCM=1.0; endif
  BMarginCM=subwrd(args,6);  if BMarginCM='';  BMarginCM=1.0; endif
  YPMarginCM=subwrd(args,7); if YPMarginCM=''; YPMarginCM=2.0; endif
  say 'xwINCH='xwINCH
  say 'latlonmag='latlonmag
  say 'TMarginCM='TMarginCM
  say 'BMarginCM='BMarginCM
  say 'YPMarginCM='YPMarginCM
else
  ywCM=subwrd(args,3)
  ywINCH=ywCM/2.54
  TMarginCM=subwrd(args,4);  if TMarginCM='';  TMarginCM=1.0; endif
  BMarginCM=subwrd(args,5);  if BMarginCM='';  BMarginCM=1.0; endif
  YPMarginCM=subwrd(args,6); if YPMarginCM=''; YPMarginCM=2.0; endif
endif
TMarginINCH=TMarginCM/2.54;
BMarginINCH=BMarginCM/2.54;
YPMarginINCH=YPMarginCM/2.54;

if (cctl='map' | cctl='MAP')
  'q dims'
  lonline=sublin(result,2)
  latline=sublin(result,3)
  say 'result from q dims='result
  if subwrd(lonline,3)='varying' & subwrd(latline,3)='varying'
    lonw=subwrd(lonline,8)-subwrd(lonline,6)
    latw=subwrd(latline,8)-subwrd(latline,6)
    'set mproj scaled'
    ywINCH=xwINCH/lonw*latlonmag*latw
  else
    say '*invalid cordinate in preay for mapping result='
    return
  endif
endif

'q gxinfo'
pline=sublin(result,2)
toppage=subwrd(pline,4)

y1=toppage-(ywINCH+BMarginINCH+TMarginINCH)*ny+BMarginINCH
y2=y1+ywINCH
return y1' 'y2


function getparea(posi)
'query gxinfo'
if (posi='left' | posi='right')
  rec3 = sublin(result,3)
  if (posi='left'); val=subwrd(rec3,4); endif
  if (posi='right'); val=subwrd(rec3,6); endif
endif
if (posi='top' | posi='bottom')
  rec4 = sublin(result,4)
  if (posi='top'); val=subwrd(rec4,6); endif
  if (posi='bottom'); val=subwrd(rec4,4); endif
endif
return val